src/continious_equation.f90

Go to the documentation of this file.

module continious_equation

  ! モジュール引用 ; Use statements
  !

  !* gtool ****
  !*

  ! 種類型パラメータ
  ! Kind type parameter
  !
  use dc_types, only: DP  ! 倍精度実数型. Double precision. 

  !* IGMBaseLib ****
  !

  ! 正二十面体格子上の物理場の管理
  ! Manager of a physical field on icosahedral grid
  !
  use Field_IcGrid2D_Manager, only: &
    & Field_IcGrid2D, &
    & Field_IcGrid2D_Init, &
    & get_icgrid, paste_field2D_margin

  ! 正二十面体格子の管理
  ! Manager of icoshedral grid
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & get_EffSize_Min, get_EffSize_Max, &
    & RC_REGIONS_NUM

  ! 正二十面体格子上の物理場に作用する微分演算子の提供
  ! Providing some differential operators acting on the physical field on icosahedral grid
  !
  use Derivate_Field_IcGrid2D_Manager, only: &
    & Derivate_Field_IcGrid2D, &
    & divergence_op

  !* IGModel-SW ****
  !*

  ! シミュレーションパラメータの管理
  ! Manager of simulation parameter
  !
  use param_manager, only: &
    & Grav, Omega, alpha
  
  ! OpenMP
  !
  !
  use omp_lib

  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  ! 公開手続き
  ! Public statements
  !
  public :: continious_equation_Init, calc_continious_eq_dhdt

  ! 非公開変数
  ! Pricate statements
  !

  type(Field_IcGrid2D), save :: mass_flux

contains

!
subroutine continious_equation_Init( &
  & icgrid                           &  ! (inout)
  & )
  
  ! 宣言文 ; Declaration statements
  !
  type(IcGrid2D_FVM), intent(inout) :: icgrid
 
  ! 実行文 ; Executable statement
  !

  !  質量フラックスを管理する構造型 Field_IcGrid2D の変数を初期化する.
  call Field_IcGrid2D_Init(self=mass_flux, icgrid=icgrid, name='mass_flux', rank=3)
 
  
end subroutine continious_equation_Init

!
subroutine calc_continious_eq_dhdt( &
  & DHeightDtN,                    &  ! (inout)
  & xy_VelN, xy_HeightN, xy_Htopo, &  ! (in)
  & diff_eval                      &  ! (inout)
  & )
 
  ! 宣言文 ; Declaration statements
  !
  type(Field_IcGrid2D), intent(inout) :: DHeightDtN
  type(Field_IcGrid2D), intent(in) :: xy_VelN
  type(Field_IcGrid2D), intent(in) :: xy_HeightN
  type(Field_IcGrid2D), intent(in) :: xy_Htopo
  type(Derivate_Field_IcGrid2D), intent(inout) :: diff_eval


  ! 作業変数
  ! Work variables
  !
  integer :: EMax, EMin
  integer :: rcID,i,j
  real(DP) :: s_pos(3)
  real(DP) :: f
  type(IcGrid2D_FVM), pointer :: icgrid

  ! 実行文 ; Executable statements
  !

  icgrid => get_icgrid(xy_velN)
  EMin = get_EffSize_Min(icgrid)
  EMax = get_EffSize_Max(icgrid)

  ! 質量フラックスを計算する.
  ! ただし, ここではマイナス符号を付加した \f$ -h\Dvect{v}\f$ を計算することにする. 
  ! Calculates the mass flux.
  ! Note that \f$ -h\Dvect{v}\f$ which is mass flux muitiplied by -1 is actually calculated here.

  do rcID=1, RC_REGIONS_NUM
    !$omp parallel do
    do j=EMin, EMax
      do i=EMin, EMax

        mass_flux%val(rcID,i,j,1:3) = &
          & - ( xy_HeightN%val(rcID,i,j,1) - xy_Htopo%val(rcID,i,j, 1) ) * xy_VelN%val(rcID,i,j,1:3)

      end do
    end do
  end do

  ! ノリシロの貼りあわせ
  call paste_field2D_margin(mass_flux)
  
  ! 質量フラックスの収束を計算し, その結果を高度の時間変化率とする.
  ! Calculates the convergence of mass flux,
  ! and the result becomes the rate of change of height wit respect to time.

  call divergence_op(diff_eval, mass_flux, DHeightDtN)
  
end subroutine calc_continious_eq_dhdt

end module continious_equation