kihon6.f: frame1
DCL:らくらくDCL:描画の基本(2):ユーザー座標系(U-座標系)での基本描画
ユーザーが実際のデータをもとに作図する過程を KIHON6 のプログラム 例をもとに考えてみましょう. ある地点の年平均気温のデータが1950年から 2000年まであり, およそセ氏16度から19度の範囲内で変動していた(第 2章のロジスティク模型の結果をちょっと細工しただけですが)と しましょう. このデータを元に平均気温の年々変動の折れ線グラフを描こう と思います. x軸を時間軸にとり1950年から2000年まで, y軸には15度から 20度を範囲として, このデータを折れ線で描くことにします.
PROGRAM KIHON6
PARAMETER( NMAX=50 )
REAL X(0:NMAX), Y(0:NMAX)
R = 3.7
X(0) = 1950
Y(0) = 0.5
DO 10 N=0,NMAX-1
X(N+1) = X(N) + 1
Y(N+1) = R*Y(N)*(1.-Y(N))
10 CONTINUE
DO 20 N=0,NMAX
Y(N) = -4*Y(N) + 20.
20 CONTINUE
WRITE(*,*) ' WORKSTATION ID (I) ? ;'
CALL SGPWSN
READ (*,*) IWS
CALL GROPN( IWS )
CALL GRFRM
CALL GRSWND( 1950., 2000., 15., 20. )
CALL GRSVPT( 0.2, 0.8, 0.2, 0.8 )
CALL GRSTRN( 1 )
CALL GRSTRF
CALL USDAXS
CALL SGPLU( NMAX+1, X, Y )
CALL GRCLS
END
PROGRAM KIHON6
ユーザーの使っている座標系(ここでは時間[年]と温度[度])を, ユーザー座標
系(U-座標系)と呼びます. U-座標系でグラフに描きたい範囲を「ウインドウ」
と呼び, それぞれの軸の最小値と最大値で設定します. この例では, ( UXMIN, UXMAX, UYMIN, UYMAX ) = ( 1950, 2000, 15, 20 )で, 25行
めのGRSWND ルーチンで設定しています. このプログラムでは30行めで
GRPH2 の USDAXS ルーチンを用いて座標軸を描くために GRxxxx
を使っていることに注意して下さい.
次に, このウインドウをV-座標系のどの範囲に対応させるかを考えて, これを
「ビューポート」と呼びます. ビューポートとは, V-座標系で通常座標軸が描
かれる矩形の領域のことです. ここでは, GRSVPT ルーチンを用いて
( VXMIN, VXMAX, VYMIN, VYMAX ) = ( 0.2, 0.8, 0.2, 0.8 ) と
設定しました.
これで, ウインドウとビューポートの四隅は対応させることができましたが,
ウインドウ内の各点をビューポート内の点に対応させる必要があります. これ
を「正規化変換」と呼びます. 線形に対応させるか, 対数をとって対応させる
かなどの任意性がありますから, 具体的に変換関数を決めなければなりません.
SGPACK(GRPACK) ではいくつかの変換関数が用意されており, それぞれに変換
関数番号が付けられています. ここでは, GRSTRN ルーチンで関数番号1
を指定しています. これは両軸ともに線形に対応させるもので, 直角一様座標
となります.
このように設定されたパラメータの値は, 変換関数を確定するルーチンGRSTRF を呼ぶことで有効になります. U-座標系で描画するためには, GRFRM ルーチンを呼んだ後でかつ描画をはじめる前に変換関数を確定する必 要があります.
さて, U-座標系での描画ですが, V-座標系での各種描画ルーチンに対応するも のが, すべて用意されています. この例では, U-座標系でのポリラインプリミ ティブ SGPLU で折れ線を描いています. 引数の与え方は全く同じで, データX, Y がU-座標系の単位で用意されています. V-座標系で の描画ルーチンのサブルーチン名が V で終っていたのに対して, U-座 標系での描画ルーチンは U で終るところが違っているだけで, 全く同 じ機能になっています.