4.4 アローとラインのサブプリミティブ

出力プリミティブには, ポリライン・ポリマーカー・テキスト・トーンの他に, 補助的にアロー(矢印)とライン(線分)のサブプリミティブがあります. アローサブプリミティブには, 矢印の軸部分のラインインデクスとラインタイプの2 つの属性があり, ラインサブプリミティブにはラインインデクスの属性があります.

プログラム KIHONC で, いろいろな矢印や線分を描いてみましょう. U-座標系での矢印描画は, SGLAU ルーチンで行ないます. 引数は, (X1,Y1) が始点の座標, (X2,Y2) が終点の座標です. 線分の終点から対称な2本の線分を付け加えて矢じり部分とします. 最初の例のように, デフォルトでは, 本体部分が長くなるのに比例して矢じり部分も大きくなります.

      PROGRAM KIHONC

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL SGOPN( IWS )
      CALL SGFRM

      CALL SGSWND( 0.0, 10.0, 0.0, 10.0 )
      CALL SGSVPT( 0.0,  1.0, 0.0,  1.0 )
      CALL SGSTRN( 1 )
      CALL SGSTRF

*-- デフォルト ----
      Y1 = 9.0
      DO 10 I=1,8
        X1 = I
        X2 = X1 + 0.1*I
        Y2 = Y1 + 0.1*I
        CALL SGLAU( X1, Y1, X2, Y2 )
   10 CONTINUE

*-- 線分のラインタイプ ----
      Y1 = 8.0
      Y2 = 8.6
      DO 20 I=1,4
        X1 = 2*I - 1
        X2 = X1 + 0.6
        CALL SGSLAT( I )
        CALL SGLAU( X1, Y1, X2, Y2 )
   20 CONTINUE

      CALL SGSLAT( 1 )

*-- 線分のラインインデクス ----
      Y1 = 7.0
      Y2 = 7.6
      DO 30 I=1,4
        X1 = 2*I
        X2 = X1 + 0.6
        CALL SGSLAI( I )
        CALL SGLAU( X1, Y1, X2, Y2 )
   30 CONTINUE

      CALL SGSLAI( 1 )

*-- 矢じり部分の長さ ----
      CALL SGLSET( 'LPROP', .FALSE. )
      CALL SGRSET( 'CONST', 0.03 )

      Y1 = 6.0
      DO 40 I=1,8
        X1 = I
        X2 = X1 + 0.1*I
        Y2 = Y1 + 0.1*I
        CALL SGLAU( X1, Y1, X2, Y2 )
   40 CONTINUE

      CALL SGLSET( 'LPROP', .TRUE. )

*-- 矢じり部分の角度 ----
      Y1 = 5.0
      Y2 = 5.6
      DO 50 I=1,8
        X1 = I
        X2 = X1 + 0.6
        CALL SGRSET( 'ANGLE', 10.0*I )
        CALL SGLAU( X1, Y1, X2, Y2 )
   50 CONTINUE

*-- 矢じり部分のぬりつぶし ----
      CALL SGLSET( 'LSOFTF', .TRUE. )
      CALL SGLSET( 'LATONE', .TRUE. )
      CALL SGISET( 'IATONE', 655 )

      Y1 = 4.0
      Y2 = 4.6
      DO 60 I=1,8
        X1 = I
        X2 = X1 + 0.6
        CALL SGRSET( 'ANGLE', 10.*I )
        CALL SGLAU( X1, Y1, X2, Y2 )
   60 CONTINUE

*-- ラインサブプリミティブ ----
*-- デフォルト ----
        CALL SGLNU( 0., 3., 10., 3. )

*-- 線分のラインインデクス ----
      Y1 = 0.5
      Y2 = 2.5
      DO 70 I=1,4
        X1 = 2*I - 1
        X2 = X1 + 2.0
        CALL SGSLNI( I )
        CALL SGLNU( X1, Y1, X2, Y2 )
   70 CONTINUE

      CALL SGCLS

      END

PROGRAM KIHONC

$\resizebox{!}{10cm}{\includegraphics{kihon2/kihonc.eps}}$
kihonc.f: frame1

SGSLAT ルーチンでは矢印を描く線分のラインタイプを, SGSLAI ルーチンではそのラインインデクスを設定できます(2番めと3番め). また,アローサブプリミティブに関する内部変数を設定し直すことにより, 矢じり部分の形状を変えることもできます. 4番めの例では, 内部変数 'LPROP' を .FALSE. として矢じり部分の長さが一定値となるようにし, その長さを内部変数 'CONST' で陽に与えました. さらに, 矢じり部分の線分と本体部分の線分のなす角を変化させたり(5番め), 矢じり部分を定義する三角形の領域を塗りつぶしたり(6番め)することにより, 多種多様な矢印が可能です.

最後に, U-座標系での線分描画は, SGLNU ルーチンで同様に行ないます. しかし, これはアローサブプリミティブの特殊な場合(矢じり部分がない場合) と考えられますので, 将来的には削除されるかも知れません.

DCLのしくみ 2
xxpGET/xxpSET で内部変数管理
地球流体電脳ライブラリでは，例えば，SGLGET/SGLSET のような内部変数管理ルーチンが多く使われています．内部変数管理ルーチンとは，設定された変数の値を保持し，問い合わせに答えて値を返す機能を持ったルーチンで，「掲示版」のような役目をするものです．この様なルーチンを使う理由として，次のようなことがあげられます．

複数のサブルーチンで情報を共有するため
サブルーチンの引数の個数を最小限にするため

複数のサブルーチンで情報を共有するには，COMMON BLOCK を使うこともできますが，大きなパッケージでこれを多用するとプログラムの可読性を落とすことにつながります．また，サブルーチンの引数を少くすると融通が効かなくなりますが，かといって，むやみに引数の数を増やすとかえって使いにくいものです．
このような問題を解決するのが内部変数管理ルーチンです．もともと「パッケージの内部で使われる変数」という意味で，内部変数という言葉を使っていますが，その変数はパッケージ外からも参照/設定できるので，その有効範囲からすると C 言語の「外部変数」に似た性格を持つものです．
内部変数管理ルーチンは xxpGET, xxpSET という名前です．xx は通常パッケージの先頭2文字で，p は変数の型によって，I（整数型）, R（実数型）, L（論理型）, C（文字型）のうちのひとつになります．内部変数は，あらかじめシステムが用意した値（初期値）をデフォルトで保持しています．この値は xxpGET ルーチンによって参照し，xxpSET ルーチンによって変更することがでます．ユーザーが何も指定しなければ初期値を使うことになります．