*"表題 第３次元の拡大 GTOOL3(GPZEXT)
*
*"履歴 91/01/19 沼口  敦
*
*
*********************************************************************
*"         << 第３次元の拡大 >>
*********************************************************************
      SUBROUTINE GPZEXT
     I         ( HHEAD , GDATA ,
     I           HAITMZ, IZSTR , IZEND ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      CHARACTER  HAITMZ      *(*)        !" 拡大する第3次元の軸名
      INTEGER    IZSTR                   !" 第3次元の軸の格子始め
      INTEGER    IZEND                   !" 第3次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
*
*"         < 1. 結合準備 >
*
      CALL GPZCMI
     I         ( HHEAD , HAITMZ, IZSTR , IZEND ,
     I           'NUL' , ' '   ,
     O           HHEADO, GDATAO )
*
*"         < 2. 大きさの取得 >
*
      CALL GUSMIS ( HHEADO )
*
      CALL GUQSIZ
     I         ( HHEADO,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR1, IZEND1, IZDIM  )
*
*"         < 3. データ詰め替え >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
*
      DO 2100 IZ = IZSTR1, IZEND1
         CALL VRSET
     I         ( GDATA                              ,
     O           GDATAO( IXDIM*IYDIM*(IZ-IZSTR1)+1 ),
     I           IXDIM*IYDIM, 1     , 1                )
 2100 CONTINUE
*
*"         < 3. ヘッダー変更 >
*
      IF ( ( IZSTR1 .EQ. 1 ).AND.( IZEND1 .EQ. 1 ) ) RETURN
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAITMZ, 'ZE'   , '-extend',
     I                 IZSTR1, IZEND1 ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第３次元の拡大 >>
*********************************************************************
      SUBROUTINE GMZEXT
     I         ( HHEAD , GDATA ,
     I           HAITMZ, IZSTR , IZEND ,
     I           HEDIT , HETTL           )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      CHARACTER  HAITMZ      *(*)        !" 拡大する第3次元の軸名
      INTEGER    IZSTR                   !" 第3次元の軸の格子始め
      INTEGER    IZEND                   !" 第3次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPZEXT
     I         ( HHEAD , GDATA ,
     I           HAITMZ, IZSTR , IZEND ,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END