4.3 もっとテキスト

プログラム KIHONB で, ちょっと進んだ文字出力をしてみましょう.

SGPACK においては '|', '_', '"'の3文字が添字の制御に使われるのですが, 何も指定しなければ, これらの文字も他の文字と同様に文字として出力されます(最初の例). SGLSET ルーチンでテキストプリミティブに関する内部変数 'LCNTL' を .TRUE. にすると, 2番めの例のように, 上付や下付の添字を出力することができます. '|'と '_'は, それぞれ, 上付添え字と下付添え字のモードの始まりをしめす制御文字で, '"'は上付および下付添え字のモードの終わりをしめす制御文字です. ここで注意すべきことは, 文字列が添字で終る場合でも, 添字の後に必ず '"'を入れて通常の文字モードに戻すことです. こうしないと文字列の長さが正確に求まらないので, センタリングや右よせ等の処理がうまくいきません. また, 添字の大きさや上下の移動量は, それぞれ SGRSET ルーチンで内部変数 'SMALL', 'SHIFT' を指定することにより変更できます(3番め).

巻末付録に示したように SGPACK は2種類のフォントを持っています. SGISET ルーチンで内部変数 'IFONT' を2とすると, フォント番号2の高品位フォントを出力することができます. 高品位フォントは複数の線を引いて線の太さを調節していますから, SGSTXI ルーチンで文字を描く線の太さを太くすると空白が潰れてそれらしい文字になります. また, 当然のことながら高品位フォントを使うと出力量が増えますから,出力に時間がかかるようになります.

フォントテーブルを見ればわかるように, SGPACK は普通のアルファベットだけでなく, ギリシャ文字や特殊記号のフォントも持っています. プログラムの 50行め以降に示したように, これらのフォント番号をDCL文字関数(SGPACK にある関数)の1つ CSGI で文字コードに変換して, それをテキストとして SGTXV ルーチン等に渡せば, 出力できます. 5行めのCHARACTER文で CSGI*1 を忘れないで下さい.

      PROGRAM KIHONB

      PARAMETER( NMAX=9 )
      REAL Y(NMAX)
      CHARACTER GREEK1*10, GREEK2*10, SYMBOL*10, CSGI*1

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL SGOPN(IWS)
      CALL SGFRM

      X1 = 0.1
      X2 = 0.9
      XC = 0.5

*-- 罫線 ----
      DO 10 N=1,NMAX
        Y(N) = 0.1*(10-N)
        CALL SGLNV( X1, Y(N), X2, Y(N) )
  10  CONTINUE

      CALL SGLNV( XC, 0.05, XC, 0.95 )

*-- デフォルト ----
      CALL SGTXV( XC, Y(1), 'SGTXV|SUP"RST_SUB"' )

*-- 添字 ----
      CALL SGLSET( 'LCNTL', .TRUE. )
      CALL SGTXV( XC, Y(2), 'SGTXV|SUP"RST_SUB"' )

      CALL SGRSET( 'SMALL', 0.5 )
      CALL SGRSET( 'SHIFT', 0.5 )
      CALL SGTXV( XC, Y(3), 'SGTXV|SUP"RST_SUB"' )

*-- フォント ----
      CALL SGTXV( XC, Y(4), 'ABCDEFG abcdefg' )

      CALL SGISET( 'IFONT', 2 )
      CALL SGTXV( XC, Y(5), 'ABCDEFG abcdefg' )

      CALL SGSTXI( 3 )
      CALL SGTXV( XC, Y(6), 'ABCDEFG abcdefg' )

      CALL SGISET( 'IFONT', 1 )
      CALL SGSTXI( 1 )

*-- ギリシャ文字 ----
      GREEK1 = CSGI(128)//CSGI(129)//CSGI(130)//CSGI(131)//CSGI(132)//
     +         CSGI(133)//CSGI(134)//CSGI(135)//CSGI(136)//CSGI(137)
      GREEK2 = CSGI(152)//CSGI(153)//CSGI(154)//CSGI(155)//CSGI(156)//
     +         CSGI(157)//CSGI(158)//CSGI(159)//CSGI(160)//CSGI(161)

      CALL SGTXV( XC, Y(7), GREEK1 )
      CALL SGTXV( XC, Y(8), GREEK2 )

*-- 特殊記号 ----
      SYMBOL = CSGI(189)//CSGI(190)//CSGI(191)//CSGI(192)//CSGI(193)//
     +         CSGI(210)//CSGI(211)//CSGI(212)//CSGI(217)//CSGI(218)

      CALL SGTXV( XC, Y(9), SYMBOL )

      CALL SGCLS

      END

PROGRAM KIHONB

$\resizebox{10cm}{!}{\includegraphics{kihon2/kihonb.eps}}$
kihonb.f: frame1