9.3 配列の一部分だけを描く

配列の一部分だけを作画するにはどうしたらよいのでしょう? これまでと同じデータで, その一部分だけを描くことを考えてみましょう(U2D4).

経度80 $^{\circ}$ から320 $^{\circ}$ , 緯度 -60 $^{\circ}$ から60 $^{\circ}$ の部分だけを描くことにします. 6行めのパラメータ文で与えているように, 格子点の範囲はx方向に9 ≦ i ≦ 33, y方向に7 ≦ j ≦ 31 となります. ウインドウの設定をこの範囲とし, 36行めのUDCNTR ルーチンで等高線図を描くのですが, ここで一工夫が必要です. 最初の引数としては, この矩形領域の左下に対応する配列要素 P(KXMN,KYMN) を陽に与え, 2 番めには実際に宣言した配列の第1次元寸法 NX, 3, 4番めには実際の作画に使う配列の第1次元および第2次元寸法 (KXMX-KXMN+1,KYMX-KYMN+1) を与えることによって配列の一部分だけを作画することができます.

この辺の事情を正しく理解するためには, FORTRAN において, 2次元の配列要素が記憶領域上でどのように順序づけられ, サブルーチンの引数にある配列がどのように扱われているかを知る必要があります. FORTRAN マニュアルなどを参照してください.

      PROGRAM U2D4

      PARAMETER( NX=37, NY=37 )
      PARAMETER( XMIN=0, XMAX=360, YMIN=-90, YMAX=90 )
      PARAMETER( PI=3.14159, DRAD=PI/180 )
      PARAMETER( KXMN=9, KXMX=33, KYMN=7, KYMX=31 )
      REAL P(NX,NY), ALON(NX), ALAT(NY)

       DO 10 I=1,NX
        ALON(I) = XMIN + (XMAX-XMIN)*(I-1)/(NX-1)
   10 CONTINUE
      DO 20 J=1,NY
        ALAT(J) = YMIN + (YMAX-YMIN)*(J-1)/(NY-1)
   20 CONTINUE

      DO 30 J=1,NY
        SLAT = SIN(ALAT(J)*DRAD)
      DO 30 I=1,NX
        P(I,J) = 3*SQRT(1-SLAT**2)*SLAT*COS(ALON(I)*DRAD)
     +         - 0.5*(3*SLAT**2-1)
   30 CONTINUE

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL GROPN( IWS )
      CALL GRFRM

      CALL GRSWND( ALON(KXMN), ALON(KXMX), ALAT(KYMN), ALAT(KYMX) )
      CALL GRSVPT(        0.2,        0.8,        0.2,        0.8 )
      CALL GRSTRN( 1 )
      CALL GRSTRF

      CALL USDAXS
      CALL UDCNTR( P(KXMN,KYMN), NX, KXMX-KXMN+1, KYMX-KYMN+1 )

      CALL GRCLS

      END

PROGRAM U2D4

$\resizebox{10cm}{!}{\includegraphics{u2d1/u2d4.eps}}$
u2d4.f: frame1

FORTRANのひけつ 2

多次元配列の記憶順序
FORTRAN77では多次元(7次元まで）の配列を定義できますが，実際の記憶装置が多次元構造を持っているわけではなくて，1次元的に管理されています．多次元配列を1次元的に展開する順序は，FORTRAN77の規格で定めてありますから，多次元配列を1次元配列と結合することが可能です．
例えば
REAL X(6), Y(2,3)
COMPLEX Z(3)
EQUIVALENCE (X,Y,Z)

という場合，変数 X, Y, Z はどれも長さが6語の配列で， EQUIVALENCE文により同じ記憶領域を占めます．この時, それぞれの変数の並び方は
　
+----------+----------+----------+----------+----------+----------+
| X(1)     | X(2)     | X(3)     | X(4)     | X(5)     | X(6)     |
|----------|----------|----------|----------|----------|----------|
| Y(1,1)   | Y(2,1)   | Y(1,2)   | Y(2,2)   | Y(1,3)   | Y(2,3)   |
|----------|----------|----------|----------|----------|----------|
| Re(Z(1)) | Im(Z(1)) | Re(Z(2)) | Im(Z(2)) | Re(Z(3)) | Im(Z(3)) |
+----------+----------+----------+----------+----------+----------+
　
という様に，2次元配列 Y は添字の左側の数字から変るように1次元的に展開されます．また，複素数データ Z は2つの実数が並んだ形で展開されます．したがって，X(3) の数値は，Y(1,2), Re(Z(2)) と同じになります．
この規則は多くのプログラムで積極的に使われており，多次元配列を1次元配列として扱ったり，複素数データを実数データと見なして処理したりすることが行われています．この規則は，計算機のハードウェアに近い部分の規則なので，計算機によって異なるように思えるかもしれませんが，FORTRAN77規格で定められた「標準語」です．例えば，「岩波FORTRAN辞典」（西村恕彦/酒井俊夫・高田正之著)の「記憶列の結合」を御覧下さい．