subroutine gtvarxformbinary(var1, var2, err)
implicit none
type(GT_VARIABLE), intent(inout):: var1, var2
logical, intent(out), optional:: err
integer:: ndim1, ndim2, ndimo
integer, allocatable:: map1(:), map2(:)
type(GT_DIMMAP), pointer:: newmap(:)
integer:: i, j, stat
character(*), parameter:: subnam = "gtvartransform-binary"
continue
call beginsub(subnam, 'mapid=[%d, %d]', i=(/var1%mapid, var2%mapid/))
call gtvar_dump(var1)
call gtvar_dump(var2)
!
! 二つの変数 var1, var2 から共有次元を調べ、対応表 map1, map2 をつくる。
!
if (present(err)) err = .false.
call inquire(var1, alldims=ndim1)
call inquire(var2, alldims=ndim2)
ndimo = max(ndim1, ndim2, 0)
allocate(map1(1:ndim1), map2(1:ndim2))
call getmatch(var1, var2, ndim1, ndim2, map1, map2)
call DbgMessage('map1=%*d map2=%*d', i=(/map1(1:ndim1), map2(1:ndim2)/), n=(/ndim1, ndim2/))
if (all(map2(1:ndim2) == 0)) then
stat = gt_enomatchdim
goto 999
endif
!
! 再配置テーブル作成開始
!
ndimo = ndim2 + count(map1(1:ndim1) == 0)
call map_allocate(newmap, ndimo)
!
! 1..ndim2 は map2 によって var2 の次元たちにマップする
!
newmap(1:ndim2)%dimno = map2(1:ndim2)
call inquire(var2, allcount=newmap(1:ndim2)%allcount)
call get_slice(var2, count=newmap(1:ndim2)%count)
do, j = 1, ndim2
if (map2(j) == 0) then
newmap(j)%start = 1
newmap(j)%stride = 1
call inquire(var2, j, url=newmap(j)%url)
else
! 位置対応によって var1 側での開始位置を決定する
call adjust_slice(var1, var2, map2(j), j, newmap(j)%start, newmap(j)%stride)
endif
enddo
!
! ndim2+1.. ndimo は var2 に対応させられない var1 の次元をおく
!
j = 0
loop1: do, i = ndim2 + 1, ndimo
do
j = j + 1
if (j > ndim1) exit loop1
if (map1(j) <= 0) exit
enddo
newmap(i)%dimno = j
call inquire(var1, dimord=j, allcount=newmap(i)%allcount)
call get_slice(var1, dimord=j, start=newmap(i)%start, count=newmap(i)%count, stride=newmap(i)%stride)
end do loop1
!
call map_apply(var1, map=newmap)
!
stat = dc_noerr
999 continue
call StoreError(stat, subnam, err)
call endsub(subnam, 'stat=%d', i=(/stat/))
deallocate(map1, map2)
return
contains
!
! 二つの次元変数を調べ、軸上位置が対応するように
! start シフト数と stride ファクタを決定する
!
subroutine adjust_slice(var1, var2, idim1, idim2, offset, stepfact)
type(GT_VARIABLE), intent(in):: var1, var2
integer, intent(in):: idim1, idim2
integer, intent(out):: offset, stepfact
type(GT_VARIABLE):: var_d
integer:: n, buf(1)
real, allocatable:: val1(:), val2(:)
continue
call beginsub('adjust_slice')
call open(var_d, source_var=var1, dimord=idim1, count_compact=.true.)
call inquire(var_d, size=n)
allocate(val1(n))
call get(var_d, val1, n)
call close(var_d)
!
call open(var_d, source_var=var2, dimord=idim2, count_compact=.true.)
call inquire(var_d, size=n)
allocate(val2(n))
call get(var_d, val2, n)
call close(var_d)
!
buf(1:1) = minloc(abs(val1(:) - val2(1)))
offset = buf(1) - 1
if (size(val2) < 2 .or. size(val1) < 2) then
stepfact = 1
else
buf(1:1) = minloc(abs(val1(:) - val2(2)))
stepfact = buf(1) - (offset + 1)
endif
!
deallocate(val1, val2)
call endsub('adjust_slice')
end subroutine