* PACKAGE APARM  !" 共通 パラメーター
*
*"  [HIS] 90/08/31(numaguti)
*"        96/09/01(takepiro)
*"        96/11/13(takepiro) TFIL 消去
*
***********************************************************************
      SUBROUTINE SETPAR      !" パラメーターのセット
     O         ( ITSTRT, ITEND , IORSTR,
     O           IDELT , INISTY    )
*
*   [PARAM] 
#ifdef SYS_IBMS
      INCLUDE   (ZCCOM)                      !" 標準物理定数
#else
#include        "zccom.F"                    !" 標準物理定数
#endif
*
*   [OUTPUT] 
      INTEGER    ITSTRT                      !" 計算開始時刻
      INTEGER    ITEND                       !" 計算終了時刻
      INTEGER    IORSTR                      !" 出力間隔：再出発
*
      INTEGER    IDELT                       !" 標準時間刻み
      INTEGER    INISTY                      !" 初期ステップ数
*
*    [INTERNAL WORK]
      INTEGER    IFPAR, JFPAR
*
*   [INTERNAL PARM]       
      CHARACTER  TUNIT  *4                   !" 時刻単位
      INTEGER    START                       !" 計算開始時刻
      INTEGER    END                         !" 計算終了時刻
      INTEGER    INTRST                      !" 出力間隔：再出発
      INTEGER    DELT                        !" 標準時間刻み
      INTEGER    INISTP                      !" 初期ステップ数
*
      NAMELIST    /NMINTG/ TUNIT , DELT  , INISTP
      NAMELIST    /NMTIME/ TUNIT , START , END   , INTRST
*
*"         < 1. 時間積分 >
*
      TUNIT  = 'MIN'
      DELT   = 30.  
      INISTP = 3
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMINTG, END=2190 )
 2190 WRITE  ( JFPAR, NMINTG )
*
      CALL GUCT2I
     I         ( DELT , TUNIT , 'SEC' , 1     ,
     O           IDELT                           )
      CALL ASUTIM
     I         ( TUNIT )
      CALL ASDELT
     I         ( IDELT )
*
*"         < 2. 時間制御 >
*
      TUNIT  = 'DAY'
      START  = 0
      END    = 1
      INTRST = 0
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMTIME, END=3190 )
 3190 WRITE  ( JFPAR, NMTIME )
*
      CALL ACTIME
     I         ( START , TUNIT  , '#'    ,
     O           ITSTRT                   )
      CALL ACTIME
     I         ( END   , TUNIT  , '#'    ,
     O           ITEND                    )
      CALL ACTIME
     I         ( INTRST, TUNIT  , '#'    ,
     O           IORSTR                   )
*
      INISTY = INISTP
*
      RETURN
      END
