*"表題 力学 境界条件 GCM5(DPHIS)
*
*"履歴  90/05/19 沼口  敦
*"      90/08/31 沼口  敦
*"      96/11/14 竹広真一
*
*
**********************************************************************
*"            << 境界条件（地形)の読み込み >>
**********************************************************************
      SUBROUTINE SETPHS
     O         ( WPHIS  ,
     I           IT      )
*
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)                      !" 格子点数，波数
      INCLUDE   (ZHDIM)                      !" 文字数
#else
#include        "zcdim.F"                    !" 格子点数，波数
#include        "zhdim.F"                    !" 文字数
#endif
*
      REAL       WPHIS ( NMDIM )             !" 地表Φ
*
      COMMON    /COMWRK/
     &           GPHIS
      REAL       GPHIS ( IDIM, JDIM )        !" 地表Φ
*
      CHARACTER  HPHIS  *(NFILN)             !" 地表Φファイル
      DATA       HPHIS / ' ' /
      NAMELIST  /NMPHIS/ HPHIS
*
      LOGICAL    OFIRST
      DATA       OFIRST / .TRUE. /
      INTEGER    ITNPHI
      DATA       ITNPHI / -999 /
*
      INTEGER    IFPAR, JFPAR
      INTEGER    IT
*
      IF ( OFIRST ) THEN
         OFIRST = .FALSE.
         CALL   REWNML ( IFPAR , JFPAR )
         READ   ( IFPAR, NMPHIS, END=1190 )
 1190    WRITE  ( JFPAR, NMPHIS )
      ENDIF
*
      IF ( IT .GE. ITNPHI ) THEN
*
*"         < 1.  地形標高Ｇ．Ｐ．の読み込み >
*
         CALL RDCON
     O         ( GPHIS , ITNPHI ,
     I           HPHIS , 'GPHIS', 0.    , 'ASFC'  , IT     )
*
*"         < 2. スペクトルに変換 >
*
      CALL G2W
     O         ( WPHIS ,
     I           GPHIS ,
     F           '    ', 'POS ', 1     )
*
      ENDIF
*
      RETURN
      END