* PACKAGE !" ヒストリーパラメータ管理
*
**********************************************************************
      SUBROUTINE HQDEFP     !" ヒストリーデフォルト参照
     O     ( FILEX , TUNITX, INTOUX, INTSUX, AVRTYX, DFORMX, INTENX,
     I       FILEM , TUNITM, INTOUM, INTSMM, AVRTYM, DFORMM         )
*
*   [OUTPUT] 
      CHARACTER  FILEX  ( 2 )*(*)             !" ファイル名
      CHARACTER  TUNITX ( 2 )*(*)             !" 時間単位
      INTEGER    INTOUX ( 2 )                 !" 出力間隔
      INTEGER    INTSUX ( 2 )                 !" 積算間隔
      CHARACTER  AVRTYX ( 2 )*(*)             !" 平均種類
      CHARACTER  DFORMX ( 2 )*(*)             !" 出力フォーマット
      INTEGER    INTENX ( 2 )                 !" ENDFILE処理間隔
*
*   [INPUT] 
      CHARACTER  FILEM       *(*)             !" ファイル名
      CHARACTER  TUNITM      *(*)             !" 時間単位
      INTEGER    INTOUM                       !" 出力間隔
      INTEGER    INTSMM                       !" 積算間隔
      CHARACTER  AVRTYM      *(*)             !" 積算間隔
      CHARACTER  DFORMM      *(*)             !" 出力フォーマット
*
#ifdef SYS_IBMS
      INCLUDE   (ZHDIM)                       !" 文字数
#else
#include        "zhdim.F"                     !" 文字数
#endif
*   [INTERNAL SAVE] 
      CHARACTER  TUNIT  ( 2 ) *(NCC)          !" 時間単位
      CHARACTER  FILE   ( 2 ) *(NFILN)        !" ファイル名
      INTEGER    INTOUT ( 2 )                 !" 出力間隔
      INTEGER    INTSUM ( 2 )                 !" 積算間隔
      CHARACTER  AVRTYP ( 2 ) *(NCC)          !" 平均種類
      CHARACTER  DFORM  ( 2 ) *(NCC)          !" 出力フォーマット
      INTEGER    INTEND ( 2 )                 !" ENDFILE処理間隔
      LOGICAL    OFIRST
      DATA       OFIRST / .TRUE. /
      SAVE
*
      NAMELIST  /NMHISD/
     &           FILE  , TUNIT , INTOUT, INTSUM, AVRTYP, DFORM , INTEND
*
*   [INTERNAL WORK] 
      INTEGER    IFPAR, JFPAR
      INTEGER    IW
*
*   [ONCE] 
      IF ( OFIRST ) THEN
         OFIRST = .FALSE.
*
         FILE  ( 1 ) = ' '
         TUNIT ( 1 ) = 'DAY'
         INTOUT( 1 ) = 1
         INTSUM( 1 ) = 1
         AVRTYP( 1 ) = ' '
         DFORM ( 1 ) = 'UR4'
         INTEND( 1 ) = 0
         FILE  ( 2 ) = '   '
         TUNIT ( 2 ) = 'DAY'
         INTOUT( 2 ) = 10
         INTSUM( 2 ) = 10
         AVRTYP( 2 ) = 'X'
         DFORM ( 2 ) = '(1PE12.4)'
         INTEND( 2 ) = 0
*
         CALL   REWNML ( IFPAR , JFPAR )
         READ   ( IFPAR, NMHISD, END=190 )
  190    WRITE  ( JFPAR, NMHISD )
      ENDIF
*
      DO 1100 IW = 1, 2
         FILEX (IW) = FILE  (IW)
         TUNITX(IW) = TUNIT (IW)
         INTOUX(IW) = INTOUT(IW)
         INTSUX(IW) = INTSUM(IW)
         AVRTYX(IW) = AVRTYP(IW)
         DFORMX(IW) = DFORM (IW)
         INTENX(IW) = INTEND(IW)
 1100 CONTINUE
*
      IF ( FILEM  .NE. ' ' ) FILEX (2) = FILEM
      IF ( TUNITM .NE. ' ' ) TUNITX(2) = TUNITM
      IF ( INTOUM .NE. 0   ) INTOUX(2) = INTOUM
      IF ( INTSMM .NE. 0   ) INTSUX(2) = INTSMM
      IF ( AVRTYM .NE. ' ' ) AVRTYX(2) = AVRTYM
      IF ( DFORMM .NE. ' ' ) DFORMX(2) = DFORMM
*
      RETURN
      END
