6.4 等間隔データをおまかせにする

これまでのプログラム USPAC1 や USPAC2 では, x 座標値の配列を宣言して等間隔に値を代入し, f(x)型の一次元図を描きましたが, これはちょっと大げさな気もします. ここで, 未定義値 RUNDEF をうまく使うと, プログラムが簡単になります. 次のプログラム USPAC3 は USPAC1 と同じ図を描くプログラムですが, x 座標値は等間隔なので, UUPACK におまかせします.

まず, 19行めで RUNDEF の値を参照し, 22行めの USGRPH ルーチンで X を指定するかわりに RUNDEF を指定します. このように, X は定義されていないと宣言すると, USGPRH は x 座標値がウインドウの幅いっぱいに等間隔にならんでいるものと解釈してグラフを描きます. このとき, USGRPH が呼ばれる前に x 方向のウインドウは決まっていないといけませんから, GRSWND ルーチンで x 方向だけを陽に与えています. ここでも, y 方向は未定義にして, 正規化変換の確定は USGPRH ルーチンにおまかせしています. 実行結果は, 前の USPAC1 の場合と全く同じです.

      PROGRAM USPAC3

      PARAMETER( NMAX=50, XMIN=1950, XMAX=2000 )
      REAL Y(0:NMAX)

      R    = 3.7
      Y(0) = 0.5
      DO 10 N=0,NMAX-1
        Y(N+1) = R*Y(N)*(1.-Y(N))
   10 CONTINUE

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL GROPN( IWS )
      CALL GRFRM

      CALL GLRGET( 'RUNDEF', RUNDEF )
      CALL GRSWND( XMIN, XMAX, RUNDEF, RUNDEF )
      CALL USSTTL( 'TIME', 'YEAR', 'HEAT FLUX', 'W/m|2"' )
      CALL USGRPH( NMAX+1, RUNDEF, Y )

      CALL GRCLS

      END

PROGRAM USPAC3

次のプログラム USPAC4 では, USSPNT や UULIN などのルーチンで Y を指定するかわりに RUNDEF を指定して, y 方向に等間隔なデータを描きます. ここで, UUMRK ルーチンはポリマーカープリミティブに対応するもので, UUSMKT, UUSMKI, UUSMKSでこのパッケージで使うマーカーの属性(種類, 描く線の太さ, 大きさ)を設定できます. USSPNT ルーチンを使ってウインドウを決め, ビューポートの設定は初期値に頼りますので, GRSTRF ルーチンの前に USPFIT を呼んでいることを再確認しておきましょう.

      PROGRAM USPAC4

      PARAMETER( NMAX=50, YMIN=0., YMAX=50. )
      REAL X1(0:NMAX), X2(0:NMAX)

      ISEED = 1
      DO 10 N=0,NMAX
        Y = YMIN + (YMAX-YMIN)*N/NMAX
        X1(N) = 10.*(EXP(-Y/20))**2 * EXP((RNGU3(ISEED)-0.5)*2)**2
        X2(N) = 10.*(EXP(-Y/20))**2
   10 CONTINUE

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL GROPN( IWS )
      CALL GRFRM

      CALL GLRGET( 'RUNDEF', RUNDEF )
      CALL GRSWND( RUNDEF, RUNDEF, YMIN, YMAX )
      CALL USSPNT( NMAX+1, X1, RUNDEF )
      CALL USSPNT( NMAX+1, X2, RUNDEF )
      CALL GRSTRN( 3 )
      CALL USPFIT
      CALL GRSTRF

      CALL USSTTL( 'MIXING RATIO', 'ppmv', 'HEIGHT', 'km' )
      CALL USDAXS

      CALL UUSMKT( 2 )
      CALL UUMRK( NMAX+1, X1, RUNDEF )
      CALL UULIN( NMAX+1, X2, RUNDEF )

      CALL GRCLS

      END

PROGRAM USPAC4

$\resizebox{10cm}{!}{\includegraphics{uspack/uspac4.eps}}$
uspac4.f: frame1

この章で紹介した正規化変換のおまかせ確定は, 「らくらくDCL」の他の章では使っていません. 教育的な配慮を優先したからで, 正規化変換の内容を陽に意識してもらいたいからです. しかし, この章で「おまかせ」の意味がはっきり分かったら, これを積極的に使って何も問題ありません. より簡単にプログラムが書けることでしょう.

DCLのしくみ 3

根回し型ルーチンと上意下達型ルーチン
SGPACK の各出力プリミティブにはそれぞれ2種類の描画ルーチンがあります．
例えば，ポリラインプリミティブでは，SGPLV, SGPLU ルーチンで折れ線を描くように説明しました．ポリラインの属性は SGSPLT, SGSPLI などのルーチンで前もって設定しておきました．これらは，いろいろ属性を決めておいてから描画ルーチンを呼ぶという「根回し型」のルーチンです．
これに対して，属性も同時に指定してポリラインを描画するルーチンも用意されています．呼び出し方法は，それぞれ，
CALL SGPLZV(N,VPX,VPY,ITYPE,INDEX)
CALL SGPLZU(N,UPX,UPY,ITYPE,INDEX)
です．引数の ITYPE でラインタイプを与え，INDEX でラインインデクスを与えます．これらは，サブルーチンひとつで一度に描いてしまう「上意下達型」のルーチンです．
同様に，他の出力プリミティブも上意下達型のルーチンが用意されています．引数の説明は省きますが，次のように呼び出します．
CALL SGPMZV(N,VPX,VPY,ITYPE,INDEX,RSIZE)
CALL SGPMZU(N,UPX,UPY,ITYPE,INDEX,RSIZE)
CALL SGTXZV(VX,VY,CHARS,RSIZE,IROTA,ICENT,INDEX)
CALL SGTXZU(UX,UY,CHARS,RSIZE,IROTA,ICENT,INDEX)
CALL SGTNZV(N,VPX,VPY,ITPAT)
CALL SGTNZU(N,UPX,UPY,ITPAT)
CALL SGLAZV(VX1,VY1,VX2,VY2,ITYPE,INDEX)
CALL SGLAZU(UX1,UY1,UX2,UY2,ITYPE,INDEX)
CALL SGLNZV(VX1,VY1,VX2,VY2,INDEX)
CALL SGLNZU(UX1,UY1,UX2,UY2,INDEX)

　
他のグラフィクスパッケージでも，GKS の流れは前者の型で，CALCOMP 系のものは後者の型です．これまでにどちらかの型に馴染んでいるユーザーは，好みの方をお使い下さい．