subroutine ModRoughLenMatthewsCultivation( xy_SurfType, xy_SurfCulInt, xy_SurfRoughLen )

    ! モジュール引用 ; USE statements
    !

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: imax, jmax, kmax    ! 鉛直層数.
                               ! Number of vertical level

    ! 宣言文 ; Declaration statements
    !
    integer , intent(in   ) :: xy_SurfType    ( 0:imax-1, 1:jmax )
    real(DP), intent(in   ) :: xy_SurfCulInt  ( 0:imax-1, 1:jmax )
    real(DP), intent(inout) :: xy_SurfRoughLen( 0:imax-1, 1:jmax )


    ! 作業変数
    ! Work variables
    !
    real(DP) :: SurfRoughLenCul
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude
    integer:: l


    ! 初期化確認
    ! Initialization check
    !
    if ( .not. roughlen_matthews_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if


    !
    ! land
    !
    SurfRoughLenCul = 0.0_DP
    do l = 1, NM84Element
      SurfRoughLenCul = SurfRoughLenCul + DataM84RL(l) * DataM84Weight( l, DataSurfCond2M84Type( IndexCultivation ) )
    end do

    do j = 1, jmax
      do i = 0, imax-1
        if( xy_SurfType(i,j) >= 1 ) then
          xy_SurfRoughLen(i,j) = ( 1.0_DP - xy_SurfCulInt(i,j) ) * xy_SurfRoughLen(i,j) + xy_SurfCulInt(i,j)              * SurfRoughLenCul
        end if
      end do
    end do


  end subroutine ModRoughLenMatthewsCultivation

  subroutine RoughLenMatthewsInit

    ! モジュール引用 ; USE statements
    !

    ! 種別型パラメタ
    ! Kind type parameter
    !
    use dc_types, only: STDOUT ! 標準出力の装置番号. Unit number of standard output

    ! ファイル入出力補助
    ! File I/O support
    !
    use dc_iounit, only: FileOpen

    ! NAMELIST ファイル入力に関するユーティリティ
    ! Utilities for NAMELIST file input
    !
    use namelist_util, only: namelist_filename, NmlutilMsg

    ! 作業変数
    ! Work variables
    !
    integer:: unit_nml        ! NAMELIST ファイルオープン用装置番号.
                              ! Unit number for NAMELIST file open
    integer:: iostat_nml      ! NAMELIST 読み込み時の IOSTAT.
                              ! IOSTAT of NAMELIST read

    integer:: l
    integer:: m


    ! NAMELIST 変数群
    ! NAMELIST group name
    !
    namelist /roughlen_Matthews_nml/ RoughLenOcean, RoughLenIce

    ! 実行文 ; Executable statement
    !

    if ( roughlen_matthews_inited ) return


    ! デフォルト値の設定
    ! Default values settings
    !

    RoughLenOcean = 1.0d-4

    RoughLenIce   = 1.0d-2


    ! NAMELIST の読み込み
    ! NAMELIST is input
    !
    if ( trim(namelist_filename) /= '' ) then
      call FileOpen( unit_nml, namelist_filename, mode = 'r' ) ! (in)

      rewind( unit_nml )
      read( unit_nml, nml = roughlen_Matthews_nml, iostat = iostat_nml )
      close( unit_nml )

      call NmlutilMsg( iostat_nml, module_name ) ! (in)
      if ( iostat_nml == 0 ) write( STDOUT, nml = roughlen_Matthews_nml )
    end if


    !
    ! This table/list is created by using Table 4 of Matthews (1983) and Table 1 of 
    ! Matthews (1984).
    !
    DataSurfCond2M84Type(  0 ) =  0 ! ocean, This is not included in Matthews papers.
    DataSurfCond2M84Type(  1 ) =  1
    DataSurfCond2M84Type(  2 ) =  1
    DataSurfCond2M84Type(  3 ) =  1
    DataSurfCond2M84Type(  4 ) =  1
    DataSurfCond2M84Type(  5 ) =  2
    DataSurfCond2M84Type(  6 ) =  3
    DataSurfCond2M84Type(  7 ) =  4
    DataSurfCond2M84Type(  8 ) =  4
    DataSurfCond2M84Type(  9 ) =  5
    DataSurfCond2M84Type( 10 ) =  6 ! A
    DataSurfCond2M84Type( 11 ) =  6 ! B, This may be 7. I cannot identify.
    DataSurfCond2M84Type( 12 ) =  8 ! C
    DataSurfCond2M84Type( 13 ) =  9 ! D
    DataSurfCond2M84Type( 14 ) = 10 ! E
    DataSurfCond2M84Type( 15 ) = 11 ! F
    DataSurfCond2M84Type( 16 ) = 12 ! G
    DataSurfCond2M84Type( 17 ) = 14 ! H
    DataSurfCond2M84Type( 18 ) = 14 ! I
    DataSurfCond2M84Type( 19 ) = 15 ! J
    DataSurfCond2M84Type( 20 ) = 15 ! K
    DataSurfCond2M84Type( 21 ) =  8 ! L
    DataSurfCond2M84Type( 22 ) = 16 ! M
    DataSurfCond2M84Type( 23 ) = 17 ! N
    DataSurfCond2M84Type( 24 ) = 17 ! O
    DataSurfCond2M84Type( 25 ) = 17 ! P
    DataSurfCond2M84Type( 26 ) = 19 ! Q
    DataSurfCond2M84Type( 27 ) = 19 ! R
    DataSurfCond2M84Type( 28 ) = 19 ! S
    DataSurfCond2M84Type( 29 ) = 19 ! T
    DataSurfCond2M84Type( 30 ) = 20 ! U
    DataSurfCond2M84Type( 31 ) = 21 ! V ice
    DataSurfCond2M84Type( 32 ) = 19 ! W cultivation

    do m = 0, NM84Type
      do l = 1, NM84Element
        DataM84Weight( l, m ) = DataM84Weight( l, m ) * 1.0d-2
      end do
    end do
    do l = 1, NM84Element
      DataM84RL( l ) = DataM84RL( l ) * 1.0d-2
    end do


    ! 印字 ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )
    call MessageNotify( 'M', module_name, 'RoughLenOcean = %f', d = (/RoughLenOcean/) )
    call MessageNotify( 'M', module_name, 'RoughLenIce   = %f', d = (/RoughLenIce/) )
    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )

    roughlen_matthews_inited = .true.

  end subroutine RoughLenMatthewsInit

  subroutine SetRoughLenLandMatthews( xy_SurfCond, xy_SurfRoughLen )

    ! モジュール引用 ; USE statements
    !

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: imax, jmax, kmax    ! 鉛直層数.
                               ! Number of vertical level

    ! 宣言文 ; Declaration statements
    !
    integer , intent(in   ) :: xy_SurfCond    ( 0:imax-1, 1:jmax )
    real(DP), intent(inout) :: xy_SurfRoughLen( 0:imax-1, 1:jmax )


    ! 作業変数
    ! Work variables
    !
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude
    integer:: l


    ! 初期化確認
    ! Initialization check
    !
    if ( .not. roughlen_matthews_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if


    !
    ! land
    !
    do j = 1, jmax
      do i = 0, imax-1
        if( xy_SurfCond( i, j ) >= 1 ) then
          xy_SurfRoughLen( i, j ) = 0.0d0
        end if
      end do
    end do
    do l = 1, NM84Element
      do j = 1, jmax
        do i = 0, imax-1
          if( xy_SurfCond( i, j ) >= 1 ) then
            xy_SurfRoughLen( i, j ) = xy_SurfRoughLen( i, j ) + DataM84RL( l ) * DataM84Weight( l, DataSurfCond2M84Type( xy_SurfCond( i, j ) ) )
          end if
        end do
      end do
    end do

    !
    ! ocean
    !
    do j = 1, jmax
      do i = 0, imax-1

        if( xy_SurfCond( i, j ) == 0 ) then
          xy_SurfRoughLen( i, j ) = RoughLenOcean
        end if

      end do
    end do

    !
    ! ice
    !
    do j = 1, jmax
      do i = 0, imax-1

        if( xy_SurfCond( i, j ) == 31 ) then
          xy_SurfRoughLen( i, j ) = RoughLenIce
        end if

      end do
    end do


  end subroutine SetRoughLenLandMatthews