dc_calendar_internal Module Reference

Functions/Subroutines
subroutine, public	default_cal_set
integer function, public	dccaldate_normalize (year, month, day, hour, min, sec, cal)
integer function, public	dccaldate_ym2d (year, month, day, cal, day_of_year)
character(token) function, public	dccaltype_str (cal_type)
character(token) function, public	dccaldate_str2ustr (str)
integer function, public	dccaldate_str2usym (str)

Variables
type(dc_cal), target, save, public	default_cal
type(dc_cal_date), target, save, public	default_date

Function/Subroutine Documentation

dccaldate_normalize()

integer function, public dc_calendar_internal::dccaldate_normalize	(	integer, intent(inout)	year,
		integer, intent(inout)	month,
		integer, intent(inout)	day,
		integer, intent(inout)	hour,
		integer, intent(inout)	min,
		real(dp), intent(inout)	sec,
		type(dc_cal), intent(in)	cal
	)

Definition at line 77 of file dc_calendar_internal.f90.

References dc_calendar_types::cal_360day, dc_calendar_types::cal_cyclic, dc_calendar_types::cal_gregorian, dc_calendar_types::cal_julian, dc_calendar_types::cal_noleap, dc_calendar_types::cal_user_defined, dc_error::dc_einconsistcaldate, and dc_error::dc_noerr.

Referenced by dccaldatechkleapyear1(), dccaldateevaldayofyear1(), dccaldateevalid1(), dccaldateevalid2(), dccaldateevalsecofday1(), dccaldateevalsecofyear1(), dccaldateevalym2ym1(), dccaldateevalym2ym2(), dccaldateevalymdhms1(), dccaldateevalymdhms2(), dccaldateinquire1(), and dccaldateinquire2().

    !
    ! 暦情報 cal に従い, 日時情報の正規化を行う. 
    ! dc_calender モジュール内部で使用されることを前提とする. 
    ! 具体的には以下の場合に正規化を実施する. 
    !
    ! * sec が cal で設定される「1 分の秒数」を超えている. 
    !   -> sec を「1 分の秒数」以内に納めるよう，年月日時分に繰り上げる．
    ! * min が cal で設定される「1 時間の分数」を超えている. 
    !   -> min を「1 時間の分数」以内に納めるよう，年月日時に繰り上げる．
    ! * hour が cal で設定される「1 日の時間数」を超えている. 
    !   -> hour を「1 日の時間数」以内に納めるよう，年月日に繰り上げる．
    ! * day が cal で設定される「1 月の日数」を超えている. 
    !   -> day を「1 月の日数」以内に納めるよう，年月に繰り上げる．
    ! 
    ! * sec, min, hour, day が負の場合. 
    !   -> それぞれを正にするよう負の分を上の位に繰り上げる．
    !
    ! * day が 0 の場合. 
    !   -> 正にするよう上の位に繰り上げる．
    !
    ! 正常に正規化が行われれば stat には DC_NOERR (=0) が返るが, 
    ! 日時情報が暦と整合的でない場合にはエラーコード DC_EINCONSISTCALDATE 
    ! が返る. 整合的であるかどうかは以下で判定する. 
    ! 
    ! * 月が, 暦情報に含まれる「1年の月数」を
    !   既に超えてしまっている場合
    !
    use dc_error, only: dc_noerr, dc_einconsistcaldate
    use dc_calendar_types, only: &
      & cal_user_defined, &
      & cal_cyclic, cal_noleap, cal_julian, cal_gregorian, cal_360day
    implicit none
    integer:: stat                      ! ステータス. Status.
    integer, intent(inout):: year       ! 年. Year.  
    integer, intent(inout):: month      ! 月. Month. 
    integer, intent(inout):: day        ! 日. Day. 
    integer, intent(inout):: hour       ! 時. Hour. 
    integer, intent(inout):: min        ! 分. Minute. 
    real(DP), intent(inout):: sec       ! 秒. Sec. 
    type(dc_cal), intent(in):: cal
                              ! 暦情報を収めたオブジェクト. 
                              ! 
                              ! An object that stores information of 
                              ! calendar. 

    ! 既定の暦での 1 ヶ月の日数
    ! Days in months of previously-defined calendars
    !
    integer:: day_in_month_jg
    integer, pointer:: day_in_month(:) =>null()

    ! 既定の暦での 1 日・時間・分の時間・分・秒数
    ! Hours, minutes, seconds in a day, a hour, a minute of previously-defined calendars
    !
    integer:: month_in_year   ! 1 日の時間数. 
                              ! Hours in a day. 
    integer:: hour_in_day     ! 1 日の時間数. 
                              ! Hours in a day. 
    integer:: min_in_hour     ! 1 時間の分数. 
                              ! Minutes in a hour. 
    real(DP):: sec_in_min     ! 1 分の秒数. 
                              ! Seconds in a minute. 

    ! 作業変数
    ! Work variables
    !
    real(DP):: wyear, wday, whour, wmin
    real(DP):: wdb, ychunk_e6, ychunk_e3, chunk_scale_e6, chunk_scale_e3
  continue
    stat = dc_noerr

    ! 日時と暦の整合性チェック
    ! Check consistency calendar and date
    !
!!$    if ( min  > cal % min_in_hour ) stat = DC_EINCONSISTCALDATE
!!$    if ( hour > cal % hour_in_day ) stat = DC_EINCONSISTCALDATE
!!$    if ( all( day  > cal % day_in_month) ) stat = DC_EINCONSISTCALDATE
    select case( cal % cal_type )
    case( cal_user_defined )
      if ( month > cal % month_in_year ) stat = dc_einconsistcaldate
    case default
      if ( month > 12 ) stat = dc_einconsistcaldate
    end select

    if ( stat /= dc_noerr ) return

    ! 秒〜日の変換パラメタ他の設定
    ! Set parameter for conversion of sec -- day, etc
    ! 
    month_in_year = cal % month_in_year
    hour_in_day   = cal % hour_in_day
    min_in_hour   = cal % min_in_hour
    sec_in_min    = cal % sec_in_min
    day_in_month => cal % day_in_month

    select case( cal % cal_type )
    case( cal_julian )
      chunk_scale_e6 = 4.0e+5
      ychunk_e6 = 146100000.0_dp

      chunk_scale_e3 = 4.0e+2
      ychunk_e3 = 146100.0_dp
    case( cal_gregorian )
      chunk_scale_e6 = 4.0e+5
      ychunk_e6 = 146097000.0_dp

      chunk_scale_e3 = 4.0e+2
      ychunk_e3 = 146097.0_dp
    case default
      chunk_scale_e6 = 1.0e+6
      ychunk_e6 = chunk_scale_e6 * sum( day_in_month(:) )

      chunk_scale_e3 = 1.0e+3
      ychunk_e3 = chunk_scale_e3 * sum( day_in_month(:) )
    end select

    ! 倍精度実数に一時的に格納
    ! Store in double precision variable temporally
    !
    wyear  = real( year, dp )
    wday   = real( day, dp )
    whour  = real( hour, dp )
    wmin   = real( min, dp )


    ! 秒 -> 分の繰り上げ
    ! Moving up sec -> min
    !
    if ( .not. sec < sec_in_min ) then
      wmin = wmin + aint( sec / sec_in_min )
      sec = mod( sec, sec_in_min )
    elseif ( sec < 0.0_dp ) then
      wdb = ceiling( abs(sec) / sec_in_min )
      wmin = wmin - wdb
      sec = sec + wdb * sec_in_min
    end if

    ! 分 -> 時の繰り上げ
    ! Moving up min -> hour
    !
    if ( .not. wmin < min_in_hour ) then
      whour = whour + aint( wmin / min_in_hour )
      wmin = mod( wmin, real( min_in_hour, DP ) )
    elseif ( wmin < 0 ) then
      wdb = ceiling( abs(wmin) / real(min_in_hour) )
      whour = whour - wdb
      wmin = wmin + wdb * min_in_hour
    end if

    ! 時 -> 日の繰り上げ
    ! Moving up hour -> day
    !
    if ( .not. whour < hour_in_day ) then
      wday = wday + aint( whour / hour_in_day )
      whour = mod( whour, real( hour_in_day, DP ) )
    elseif ( whour < 0 ) then
      wdb = ceiling( abs(whour) / real(hour_in_day) )
      wday = wday - wdb
      whour = whour + wdb * hour_in_day
    end if

    ! 日が負もしくは 0 の場合，負の部分を年に繰り上げ，日を正に変換
    ! Negative or 0 part of day is moved up to year
    !
    if ( wday < 1.0_dp ) then
      select case( cal % cal_type )
      case( cal_julian )

        do while ( wday < 1.0_dp )

          if ( wday < - ychunk_e6 ) then
            wyear = wyear + chunk_scale_e6 * ( aint( wday / ychunk_e6 ) - 1.0_dp )
            wday = mod( wday, ychunk_e6 ) + ychunk_e6
          end if

          if ( wday < 1.0_dp ) then
            wyear = wyear + chunk_scale_e3 * ( aint( wday / ychunk_e3 ) - 1.0_dp )
            wday = mod( wday, ychunk_e3 ) + ychunk_e3
          end if

        end do

      case( cal_gregorian )

        do while ( wday < 1.0_dp )

          if ( wday < - ychunk_e6 ) then
            wyear = wyear + chunk_scale_e6 * ( aint( wday / ychunk_e6 ) - 1.0_dp )
            wday = mod( wday, ychunk_e6 ) + ychunk_e6
          end if

          if ( wday < 1.0_dp ) then
            wyear = wyear + chunk_scale_e3 * ( aint( wday / ychunk_e3 ) - 1.0_dp )
            wday = mod( wday, ychunk_e3 ) + ychunk_e3
          end if

        end do

      case default

        do while ( wday < 1.0_dp )

          if ( wday < - ychunk_e6 ) then
            wyear = wyear + chunk_scale_e6 * ( aint( wday / ychunk_e6 ) - 1.0_dp )
            wday = mod( wday, ychunk_e6 ) + ychunk_e6
          end if

          if ( wday < 1.0_dp ) then
            wyear = wyear + chunk_scale_e3 * ( aint( wday / ychunk_e3 ) - 1.0_dp )
            wday = mod( wday, ychunk_e3 ) + ychunk_e3
          end if

        end do

      end select

    end if

    ! 日 -> 年月の繰り上げ
    ! Moving up day -> year and month
    !
    select case( cal % cal_type )
    case( cal_julian )

      if ( wday > ychunk_e6 ) then
        wyear = wyear + chunk_scale_e6 * aint( wday / ychunk_e6 )
        wday = mod( wday, ychunk_e6 )
      end if

      if ( wday > ychunk_e3 ) then
        wyear = wyear + chunk_scale_e3 * aint( wday / ychunk_e3 )
        wday = mod( wday, ychunk_e3 )
      end if

      do
        if ( month == 2 ) then
          if ( mod( wyear, 4.0_dp ) == 0 ) then
            day_in_month_jg = 29
          else
            day_in_month_jg = 28
          end if
        else
          day_in_month_jg = day_in_month(month)
        end if

        if ( .not. wday > day_in_month_jg ) exit

        wday = wday - day_in_month_jg
        month = month + 1
        if ( month > month_in_year ) then
          month = 1
          wyear = wyear + 1
        end if
      end do

    case( cal_gregorian )

      if ( wday > ychunk_e6 ) then
        wyear = wyear + chunk_scale_e6 * aint( wday / ychunk_e6 )
        wday = mod( wday, ychunk_e6 )
      end if

      if ( wday > ychunk_e3 ) then
        wyear = wyear + chunk_scale_e3 * aint( wday / ychunk_e3 )
        wday = mod( wday, ychunk_e3 )
      end if

      do
        if ( month == 2 ) then
          if ( mod( wyear, 400.0_dp ) == 0 ) then
            day_in_month_jg = 29
          elseif ( mod( wyear, 100.0_dp ) == 0 ) then
            day_in_month_jg = 28
          elseif ( mod( wyear, 4.0_dp ) == 0 ) then
            day_in_month_jg = 29
          else
            day_in_month_jg = 28
          end if
        else
          day_in_month_jg = day_in_month(month)
        end if

        if ( .not. wday > day_in_month_jg ) exit

        wday = wday - day_in_month_jg
        month = month + 1
        if ( month > month_in_year ) then
          month = 1
          wyear = wyear + 1
        end if
      end do

    case default

      if ( wday > ychunk_e6 ) then
        wyear = wyear + chunk_scale_e6 * aint( wday / ychunk_e6 )
        wday = mod( wday, ychunk_e6 )
      end if

      if ( wday > ychunk_e3 ) then
        wyear = wyear + chunk_scale_e3 * aint( wday / ychunk_e3 )
        wday = mod( wday, ychunk_e3 )
      end if

      do while ( wday > day_in_month(month) )
        wday = wday - day_in_month(month)
        month = month + 1
        if ( month > month_in_year ) then
          month = 1
          wyear = wyear + 1
        end if
      end do

    end select

    ! 整数に戻す
    ! Return to integer
    !
    year  = wyear 
    day   = wday  
    hour  = whour 
    min   = wmin  

Here is the caller graph for this function:

dccaldate_str2ustr()

character(token) function, public dc_calendar_internal::dccaldate_str2ustr

(

character(*), intent(in)

str

)

Definition at line 530 of file dc_calendar_internal.f90.

References dc_types::token, dc_calendar_types::unit_day, dc_calendar_types::unit_hour, dc_calendar_types::unit_min, dc_calendar_types::unit_month, dc_calendar_types::unit_sec, and dc_calendar_types::unit_year.

    !
    ! 引数 *str* に与えられた文字列を解釈し, 日時の単位を *unit* に返す. 
    ! それぞれ以下の文字列が日時の単位として解釈される.
    ! 大文字と小文字は区別されない. 
    ! 返る文字列は以下の文字型の配列の先頭の文字列となる. 
    ! (例: *str* に 'hrs.' が与えられる場合, dc_calendar_types#UNIT_HOUR
    ! 配列の先頭の文字列 UNIT_HOUR(1) が返る.)
    !
    ! 年         :: dc_calendar_types#UNIT_YEAR
    ! 月         :: dc_calendar_types#UNIT_MONTH
    ! 日         :: dc_calendar_types#UNIT_DAY
    ! 時         :: dc_calendar_types#UNIT_HOUR
    ! 分         :: dc_calendar_types#UNIT_MIN
    ! 秒         :: dc_calendar_types#UNIT_SEC
    !
    ! これらに該当しない文字列を *str* に与えた場合, 空文字が返る. 
    !
    use dc_types, only: token
    use dc_calendar_types, only: unit_year, unit_month, unit_day, &
      & unit_hour, unit_min, unit_sec
    use dc_string, only: strieq
    implicit none
    character(*), intent(in):: str
    character(TOKEN):: unit
    integer :: unit_str_size, i
  continue
    unit = adjustl(str)

    unit_str_size = size(unit_sec)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_sec(i)))) then
        unit = unit_sec(1)
        return
      end if
    end do

    unit_str_size = size(unit_min)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_min(i)))) then
        unit = unit_min(1)
        return
      end if
    end do

    unit_str_size = size(unit_hour)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_hour(i)))) then
        unit = unit_hour(1)
        return
      end if
    end do

    unit_str_size = size(unit_day)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_day(i)))) then
        unit = unit_day(1)
        return
      end if
    end do

    unit_str_size = size(unit_month)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_month(i)))) then
        unit = unit_month(1)
        return
      end if
    end do

    unit_str_size = size(unit_year)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_year(i)))) then
        unit = unit_year(1)
        return
      end if
    end do

    unit = ''

dccaldate_str2usym()

integer function, public dc_calendar_internal::dccaldate_str2usym

(

character(*), intent(in)

str

)

Definition at line 611 of file dc_calendar_internal.f90.

References dc_types::token, dc_calendar_types::unit_day, dc_calendar_types::unit_hour, dc_calendar_types::unit_min, dc_calendar_types::unit_month, dc_calendar_types::unit_sec, dc_calendar_types::unit_symbol_day, dc_calendar_types::unit_symbol_err, dc_calendar_types::unit_symbol_hour, dc_calendar_types::unit_symbol_min, dc_calendar_types::unit_symbol_month, dc_calendar_types::unit_symbol_sec, dc_calendar_types::unit_symbol_year, and dc_calendar_types::unit_year.

Referenced by dccalconvertbyunit1(), dccalconvertbyunit2(), dccalconverttoday1(), dccalconverttoday2(), dccalconverttohour1(), dccalconverttohour2(), dccalconverttomin1(), dccalconverttomin2(), dccalconverttosec1(), dccalconverttosec2(), dccaldatedifference1(), dccaldateevalid2(), dccaldateevalym2ym2(), dccaldateevalymdhms2(), and dccalparseunit1().

    !
    ! 引数 *str* に与えられた文字列を解釈し, 日時の単位を示す
    ! 整数 *symbol* を返す. それぞれ以下の文字列が日時の単位として解釈する.
    ! 大文字と小文字は区別しない.
    !
    ! 年         :: dc_calendar_types#UNIT_YEAR
    ! 月         :: dc_calendar_types#UNIT_MONTH
    ! 日         :: dc_calendar_types#UNIT_DAY
    ! 時         :: dc_calendar_types#UNIT_HOUR
    ! 分         :: dc_calendar_types#UNIT_MIN
    ! 秒         :: dc_calendar_types#UNIT_SEC
    !
    ! 返るシンボル (整数型) は以下の通り. 
    !
    ! 年         :: dc_calendar_types#UNIT_SYMBOL_YEAR
    ! 月         :: dc_calendar_types#UNIT_SYMBOL_MONTH
    ! 日         :: dc_calendar_types#UNIT_SYMBOL_DAY
    ! 時         :: dc_calendar_types#UNIT_SYMBOL_HOUR
    ! 分         :: dc_calendar_types#UNIT_SYMBOL_MIN
    ! 秒         :: dc_calendar_types#UNIT_SYMBOL_SEC
    !
    ! これらに該当しない文字列を *str* に与えた場合, 
    ! dc_calendar_types#UNIT_SYMBOL_ERR が返る. 
    !
    use dc_types, only: token
    use dc_calendar_types, only: unit_year, unit_month, unit_day, &
      & unit_hour, unit_min, unit_sec, &
      & unit_symbol_year, unit_symbol_month, unit_symbol_day, &
      & unit_symbol_hour, unit_symbol_min, unit_symbol_sec, &
      & unit_symbol_err
    use dc_string, only: strieq
    implicit none
    character(*), intent(in):: str
    integer:: symbol
    integer:: unit_str_size, i
    character(TOKEN):: unit
  continue
    unit = adjustl(str)

    unit_str_size = size(unit_sec)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_sec(i)))) then
        symbol = unit_symbol_sec
        return
      end if
    end do

    unit_str_size = size(unit_min)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_min(i)))) then
        symbol = unit_symbol_min
        return
      end if
    end do

    unit_str_size = size(unit_hour)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_hour(i)))) then
        symbol = unit_symbol_hour
        return
      end if
    end do

    unit_str_size = size(unit_day)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_day(i)))) then
        symbol = unit_symbol_day
        return
      end if
    end do

    unit_str_size = size(unit_month)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_month(i)))) then
        symbol = unit_symbol_month
        return
      end if
    end do

    unit_str_size = size(unit_year)
    do i = 1, unit_str_size
      if (strieq(trim(unit), trim(unit_year(i)))) then
        symbol = unit_symbol_year
        return
      end if
    end do

    symbol = unit_symbol_err

Here is the caller graph for this function:

dccaldate_ym2d()

integer function, public dc_calendar_internal::dccaldate_ym2d	(	integer, intent(in)	year,
		integer, intent(in)	month,
		integer, intent(in)	day,
		type(dc_cal), intent(in)	cal,
		real(dp), intent(out)	day_of_year
	)

Definition at line 403 of file dc_calendar_internal.f90.

References dc_calendar_types::cal_360day, dc_calendar_types::cal_cyclic, dc_calendar_types::cal_gregorian, dc_calendar_types::cal_julian, dc_calendar_types::cal_noleap, dc_calendar_types::cal_user_defined, dc_error::dc_einconsistcaldate, and dc_error::dc_noerr.

Referenced by dccaldatechkleapyear1(), dccaldateevaldayofyear1(), dccaldateevalsecofday1(), and dccaldateevalsecofyear1().

    !
    ! 暦情報 cal に従い, 月日をその年が始まった時からの通日に変換する. 
    ! 結果は倍精度実数として *day_of_year* に返る. 
    ! dccaldate_normalize によって正規化した後に呼び出すこと. 
    !
    use dc_error, only: dc_noerr, dc_einconsistcaldate
    use dc_calendar_types, only: &
      & cal_user_defined, &
      & cal_cyclic, cal_noleap, cal_julian, cal_gregorian, cal_360day
    implicit none
    integer:: stat                      ! ステータス. Status.
    integer, intent(in):: year          ! 年. Year.  
    integer, intent(in):: month         ! 月. Month. 
    integer, intent(in):: day           ! 日. Day. 
    real(DP), intent(out):: day_of_year ! 年始からの通日. Day of year
    type(dc_cal), intent(in):: cal
                              ! 暦情報を収めたオブジェクト. 
                              ! 
                              ! An object that stores information of 
                              ! calendar. 

    ! 作業変数
    ! Work variables
    !
    integer:: i

  continue
    stat = dc_noerr

    ! 日時と暦の整合性チェック
    ! Check consistency calendar and date
    !
!!$    if ( min  > cal % min_in_hour ) stat = DC_EINCONSISTCALDATE
!!$    if ( hour > cal % hour_in_day ) stat = DC_EINCONSISTCALDATE
!!$    if ( all( day  > cal % day_in_month) ) stat = DC_EINCONSISTCALDATE
    select case( cal % cal_type )
    case( cal_user_defined )
      if ( month > cal % month_in_year ) stat = dc_einconsistcaldate
    case default
      if ( month > 12 ) stat = dc_einconsistcaldate
    end select

    if ( stat /= dc_noerr ) return

    ! 倍精度実数に一時的に格納
    ! Store in double precision variable temporally
    !
    day_of_year  = real( day, dp )

    ! 年月 -> 日 の繰り下げ
    ! Moving doun year and month -> day
    !
    select case( cal % cal_type )
    case( cal_julian )

      do i = 1, month - 1
        if ( i == 2 ) then
          if ( mod( year, 4 ) == 0 ) then
            day_of_year = day_of_year + 29
          else
            day_of_year = day_of_year + 28
          end if
        else
          day_of_year = day_of_year + cal % day_in_month(i)
        end if
      end do

    case( cal_gregorian )

      do i = 1, month - 1
        if ( i == 2 ) then
          if ( mod( year, 400 ) == 0 ) then
            day_of_year = day_of_year + 29
          elseif ( mod( year, 100 ) == 0 ) then
            day_of_year = day_of_year + 28
          elseif ( mod( year, 4 ) == 0 ) then
            day_of_year = day_of_year + 29
          else
            day_of_year = day_of_year + 28
          end if
        else
          day_of_year = day_of_year + cal % day_in_month(i)
        end if

      end do

    case default

      do i = 1, month - 1
        day_of_year = day_of_year + cal % day_in_month(i)
      end do

    end select

Here is the caller graph for this function:

dccaltype_str()

character(token) function, public dc_calendar_internal::dccaltype_str

(

integer, intent(in)

cal_type

)

Definition at line 501 of file dc_calendar_internal.f90.

References dc_calendar_types::cal_360day, dc_calendar_types::cal_cyclic, dc_calendar_types::cal_gregorian, dc_calendar_types::cal_julian, dc_calendar_types::cal_noleap, dc_calendar_types::cal_user_defined, and dc_types::token.

Referenced by dccalconvertbyunit1(), dccalconvertbyunit2(), dccalconverttoday1(), dccalconverttoday2(), dccalconverttohour1(), dccalconverttohour2(), dccalconverttomin1(), dccalconverttomin2(), dccalconverttosec1(), dccalconverttosec2(), dccaldatedifference1(), dccalinquire1(), and dccaltochar1().

    !
    ! 整数型の暦タイプ *cal_type* を文字列 *str* に変換する. 
    ! 不正な *cal_type* の場合は空文字が返る. 
    ! 
    use dc_calendar_types, only: &
      & cal_user_defined, &
      & cal_cyclic, cal_noleap, cal_julian, cal_gregorian, cal_360day
    use dc_types, only: token
    implicit none
    character(TOKEN):: str
    integer, intent(in):: cal_type

    ! 作業変数
    ! Work variables
    !
  continue
    select case( cal_type )
    case(cal_user_defined) ; str = 'user_defined'
    case(cal_cyclic)       ; str = 'cyclic      '
    case(cal_noleap)       ; str = 'noleap      '
    case(cal_julian)       ; str = 'julian      '
    case(cal_gregorian)    ; str = 'gregorian   '
    case(cal_360day)       ; str = '360day      '
    case default           ; str = '            '
    end select

Here is the caller graph for this function:

default_cal_set()

subroutine, public dc_calendar_internal::default_cal_set

(

)

Definition at line 44 of file dc_calendar_internal.f90.

References dc_calendar_types::cal_gregorian, and default_cal.

Referenced by dccalconvertbyunit1(), dccalconvertbyunit2(), dccalconverttoday1(), dccalconverttoday2(), dccalconverttohour1(), dccalconverttohour2(), dccalconverttomin1(), dccalconverttomin2(), dccalconverttosec1(), dccalconverttosec2(), dccaldatechkleapyear1(), dccaldatedifference1(), dccaldateevaldayofyear1(), dccaldateevalid1(), dccaldateevalid2(), dccaldateevalsecofday1(), dccaldateevalsecofyear1(), dccaldateevalym2ym1(), dccaldateevalym2ym2(), dccaldateevalymdhms1(), dccaldateevalymdhms2(), dccaldateinquire1(), dccaldateinquire2(), dccaldefault1(), and dccalinquire1().

    ! 
    ! DCCal で始まる手続が呼び出され, "dc_calendar_types#DC_CAL" 型の
    ! 引数に暦の設定が行われていない場合には, まずこの手続を呼び出して, 
    ! デフォルトの暦 "default_cal" をグレゴリオ暦として設定する. 
    ! 
    ! 既に "default_cal" に暦が設定されている場合にはこの手続
    ! 内でそれを判定して何もせずに手続を終了するため, 
    ! この手続は何度呼び出しても良く, 呼び出す側で状態の有無を
    ! 確認する必要はない. 
    ! 
    use dc_calendar_types, only: cal_gregorian
    implicit none
    type(dc_cal), pointer:: calp =>null()
  continue
    calp => default_cal

    if ( calp % initialized ) return

    calp % cal_type = cal_gregorian
    calp % month_in_year = 12
    calp % hour_in_day   = 24
    calp % min_in_hour   = 60
    calp % sec_in_min    = 60.0_dp
    allocate( calp % day_in_month(1:12) )
    calp % day_in_month(1:12) = &
      & (/ 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 /)

    calp % initialized = .true.
    nullify( calp )

Here is the caller graph for this function:

Variable Documentation

default_cal

type(dc_cal), target, save, public dc_calendar_internal::default_cal

Definition at line 24 of file dc_calendar_internal.f90.

Referenced by dccalconvertbyunit1(), dccalconvertbyunit2(), dccalconverttoday1(), dccalconverttoday2(), dccalconverttohour1(), dccalconverttohour2(), dccalconverttomin1(), dccalconverttomin2(), dccalconverttosec1(), dccalconverttosec2(), dccalcreate1(), dccalcreate2(), dccaldatechkleapyear1(), dccaldatedifference1(), dccaldateevaldayofyear1(), dccaldateevalid1(), dccaldateevalid2(), dccaldateevalsecofday1(), dccaldateevalsecofyear1(), dccaldateevalym2ym1(), dccaldateevalym2ym2(), dccaldateevalymdhms1(), dccaldateevalymdhms2(), dccaldateinquire1(), dccaldateinquire2(), dccaldefault1(), dccalinquire1(), and default_cal_set().

  type(dc_cal), save, target, public:: default_cal

default_date

type(dc_cal_date), target, save, public dc_calendar_internal::default_date

Definition at line 33 of file dc_calendar_internal.f90.

Referenced by dccaldatechkleapyear1(), dccaldatecreate1(), dccaldatecreate2(), dccaldatecurrent1(), dccaldateevaldayofyear1(), dccaldateevalid1(), dccaldateevalid2(), dccaldateevalsecofday1(), dccaldateevalsecofyear1(), dccaldateevalym2ym1(), dccaldateevalym2ym2(), dccaldateevalymdhms1(), dccaldateevalymdhms2(), dccaldateinquire1(), and dccaldateinquire2().

  type(dc_cal_date), save, target, public:: default_date